!!! LAB 5: Fluid-structure interaction
! by AM, 2018.04.18.

! Defining the parameters
r1=0.254 ! inner radius of the ring
r2=0.26035 ! outer radius of the ring
! inner radius of the fluid region
r3=0.5209 ! outer radius of the fluid region
E=206.8e9 ! elastic modulus of the ring (steel)
nu=0.3 ! Poisson ration of the ring
rho=7929 ! density of the ring
rhow=1030 ! density of the water
c=1460 ! sonic velocity in the water

!! Creating the model
/PREP7
! Element type and material
ET,1,PLANE182 ! solid plane element for the ring
ET,2,FLUID29 ! plane element for the fluid
ET,3,FLUID129 ! 1D element for the external boundary of the fluid
R,3,r3,0,0 ! radius of curvature of the boundary element
MP,EX,1,E ! material properties of the ring (model 1)
MP,PRXY,1,nu
MP,DENS,1,rho
MP,DENS,2,rhow ! material properties of the water (model 2)
MP,SONC,2,c
! Geometry
CYL4,0,0,r1,0,r2,90 ! ring (quarter)
CYL4,0,0,r2,0,r3,90 ! water (quarter)
ARSYM,X,ALL ! reflection for the full model
ARSYM,Y,ALL
AGLUE,ALL ! glueing all areas (merging lines)
! Meshing
LSEL,S,radius,,r1 ! selecting the inner arcs
ASLL ! selecting the areas of the ring
AATT,1,,1 ! settin the material model and the element type
ALLSEL
LSEL,S,radius,,r3 ! selecting the outer arcs
ASLL ! selecting the areas of the water
AATT,2,,2
ALLSEL
LSEL,S,radius,,r1,r3 ! selectin all arcs
LESIZE,ALL,,,16 ! element number (16 per line)
ALLSEL
LSEL,S,length,,r3-r2 ! selecting the axial lines of the water
LESIZE,ALL,,,5 ! element number (5 per line)
ALLSEL
LSEL,S,lenght,,r2-r1 ! selecting the axial lines of the ring
LESIZE,ALL,,,1 ! element number (1 per line)
ALLSEL
AMESH,ALL ! meshing the areas
LSEL,S,radius,,r3 ! selecting the outer arcs
NSLL,S,1 ! selecting nodes at the outer interface
TYPE,3 ! picking element type 3 (fluid boundary)
MAT,2 ! picking material model 2 (water)
REAL,3 ! picking real constant set 3 (fluid boundary)
ESURF ! generating the boundary elements between selected nodes
ALLSEL
! The mesh at this point:</br><img src='images/mesh.png' height='500px'>
FINISH

!! Loads and solution
/SOLU
ANTYPE,HARMIC ! analysis type: harmonic analysis
HROPT,FULL ! full solver for unsymmetric matrices
EQSLV,SPARSE ! sparse matrix solver
LSEL,S,radius,,r2 ! selecting the interface lines
NSLL,S,1 ! selecting the attached nodes
ESLN,S ! selecting the attached elements
ESEL,R,type,,2 ! selecting the fluid elements only
SF,ALL,FSI,1 ! setting fluid-solid interaction
ALLSEL
KSEL,S,loc,x,r1 ! selecting the keypoint on the inner radius,
! right side
NSLK,S ! selecting the attached node
F,ALL,FX,1000 ! force constraint on the node
ALLSEL
KSEL,S,loc,x,-r1 ! selecting the kexpoint on the inner radius,
! left side
NSLK,S
F,ALL,FX,-1000
ALLSEL
HARFRQ,10,120 ! freqency range: 10 to 120 Hz
NSUBST,100 ! number of substeps: 100
KBC,1 ! load stepping: stepped (in increments)
SOLVE ! solution
SAVE
FINISH

!! Visualising the results
/POST26 ! entering the time-history postprocessing module
FILE,,'rst' ! loading the result file
KSEL,S,loc,x,r1 ! selecting the right inner node at the X axis
NSLK,S
*GET,numm,NODE,,NUM,MAX ! saving the node number in the variable "numm"
NSOL,2,numm,U,X ! displacement in the different frequiencies (variable 2)
XVAR,1 ! set x coordinate of the graph (frequency)
PLVAR,2 ! draw the resonance curve on graph
! Resonance curve:</br><img src='images/amplitude.png' height='500px'>
/POST1 ! entering the general postprocessing module
SET,,,,,90 ! loading the load step of 90 Hz
PLDISP,2 ! drawing the deformed shape
! Deformed shape:</br><img src='images/pldisp.png' height='500px'>
PLNSOL,U,SUM ! plotting displacement sum
! Contour plot:</br><img src='images/plnsol.png' height='500px'>
!ANCNTR,10,0.1 ! animating the vibration
! Animation:</br><img src='images/anim.gif' height='500px'>