/PREP7		! Enters the preprocessor phase
*SET,L,1000
*SET,S,50
*SET,elems,201
*SET,tasknum,10
! Array for results
*DIM,displ,ARRAY,tasknum		! Creates a 1D array with 5 elems
*DO,i,0,elems,2
	*SET,x,i*S
	K,,x,0	
	K,,x,200+50*SIN(x/200)
*ENDDO
*DO,i,1,elems-2,2
	L,i,i+2
	L,i+1,i+3
*ENDDO
*DO,i,1,elems-8,8
	L,i,i+1
	L,i,i+5
	L,i+4,i+5
	L,i+5,i+8
*ENDDO
L,elems,elems+1
! Create BEAM188 element type
ET,1,BEAM188
! Material props
MPTEMP,1,0  
MPDATA,EX,1,,2e5
MPDATA,PRXY,1,,0.3
! Beam section
SECTYPE,   1, BEAM, RECT, BSEC1, 0  
SECOFFSET, CENT 
SECDATA,5,5,
*DO,divisions,1,tasknum,1
	! Re-enter prep
	/PREP7
	! Clear mesh (if exists)
	LCLEAR,ALL
	! Meshing
	LESIZE,ALL,,,divisions, ,1, , ,1, 
	LMESH,ALL
	! Displ constraint
	D,NODE(0,0,0),,,,,,ALL, , , , ,
	D,NODE(x,0,0),,,,,,ALL
	! Force
	F,NODE(x/2,0,0),FY,-1000  
	FINISH  
	/SOL		! Enters the solution phase
	SOLVE		! Runs the solver
	FINISH
	/POST1  	! Enters the postproc. phase
	PLDISP,1	! Displays the deformed shape
	*GET,displ(divisions),NODE,NODE(x/2,0,0),U,Y
	FINISH
*ENDDO
*MWRITE,displ,'results',txt		! Prints an array to file
%12.6F